Exploring Analyic Geometry with Mathematica®

Home Contents Commands Packages Explorations Reference
Tour Lines Circles Conics Analysis Tangents

Area of a Conic Arc (General)

caarea1.html

Exploration

For the conic arc whose control points are (0,0), (a,b) and (d,0), show that the area between the conic arc and its chord is given by

"caarea1_1.gif"

where "caarea1_2.gif" (ρ≠1/2).  Assume b>0 and d>0.

Approach

Construct the conic arc in the given position and use integration to find the area.

Initialize

To initialize Descarta2D, select the input cell bracket and press SHIFT-Enter.

This initialization assumes that the Descarta2D software has been copied into one of the standard directories for AddOns which are on the Mathematica search path, $Path.

<<Descarta2D`

Solution

Construct the conic arc.

Clear[a,b,d,p];
ca1=ConicArc2D[{0,0},{a,b},{d,0},p];

Determine the coordinates of a point at parameter t.

Clear[t];
{X1,Y1}=ca1[t] //FullSimplify

"caarea1_3.gif"

Form an implicit equation of the curve by eliminating t.

Clear[x,y];
eq1=Eliminate[{x==X1,y==Y1},t]

"caarea1_4.gif"

Solve the implicit equation for x.

ans=(Solve[eq1,x] //FullSimplify )//. {
Power[e1___*Power[b,2]*f1___,1/2]->b*Sqrt[e1*f1],
Power[e2___*Power[d,2]*f2___,1/2]->d*Sqrt[e2*f2],
Power[e3___*Power[p,2]*f3___,1/2]->p*Sqrt[e3*f3]} //FullSimplify

"caarea1_5.gif"

The length, L, of an area element in terms of y is the difference between the two x locations on the curve.

L=((x /. ans[[2,1]])-(x /. ans[[1,1]]) //FullSimplify)//. {
Power[e1___*Power[b,2]*f1___,1/2]->b*Sqrt[e1*f1],
Power[e2___*Power[d,2]*f2___,1/2]->d*Sqrt[e2*f2],
Power[e3___*Power[p,2]*f3___,1/2]->p*Sqrt[e3*f3]} //FullSimplify

"caarea1_6.gif"

The area between the curve and the x-axis is the integral of L evaluated between the limits on the y-axis.

Clear[E1,E2,r];
A1=Integrate[L,{y,0,b*p},Assumptions->{p>0,p<1,b>0,d>0}] //FullSimplify

"caarea1_7.gif"

This is the area formula given in the exploration statement above.

A2=b*d*p*(p*r+(-1+p)^2*Log[(1-p)/
      (p+r)])/(2*r^3) /. r->Sqrt[-1+2*p]

"caarea1_8.gif"

The area under the curve is the same as the area given by the formula.

IsZero2D[A1-A2]

"caarea1_9.gif"


Copyright © 1999-2007 Donald L. Vossler, Descarta2D Publishing
www.Descarta2D.com