Exploring Analyic Geometry with Mathematica®

Home Contents Commands Packages Explorations Reference
Tour Lines Circles Conics Analysis Tangents

Focal Distances of a Hyperbola

hyp2a.html

Exploration

Show that the difference of the distances from the two foci to any point on a hyperbola is 2a, where a is the length of the semi-transverse axis.

Approach

Construct a generic point on a hyperbola.  Construct the two foci of the hyperbola. Find the distance from each focus to the generic point.  Show that the difference of the distances is 2a.

Initialize

To initialize Descarta2D, select the input cell bracket and press SHIFT-Enter.

This initialization assumes that the Descarta2D software has been copied into one of the standard directories for AddOns which are on the Mathematica search path, $Path.

<<Descarta2D`

Solution

Create the hyperbola and a generic point on it.

Clear[a,b,t];
h1=Hyperbola2D[{0,0},a,b,0];
p1=Point2D[a*Cosh[t],b*Sinh[t]]

"hyp2a_1.gif"

Create the focus points of the hyperbola.

{f1,f2}=Foci2D[h1]

"hyp2a_2.gif"

Compute the difference of the distances from the generic point to the foci.

diff1=Distance2D[p1,f2]-Distance2D[p1,f1]

"hyp2a_3.gif"

Work on the expressions under the radicals.

{e1,e2}=Map[Expand[# /. Sinh[t]^2->Cosh[t]^2-1]&,
            {diff1[[1,2,1]],diff1[[2,1]]}]

"hyp2a_4.gif"

This shows that both expressions factor into perfect squares.

{(e3=(a-Sqrt[a^2+b^2]*Cosh[t])^2)-e1,
(e4=(a+Sqrt[a^2+b^2]*Cosh[t])^2)-e2} //Expand

"hyp2a_5.gif"

Replace the expressions under the radicals with the equivalent perfect square expressions.

diff2=-Sqrt[e3]+Sqrt[e4]

"hyp2a_6.gif"

Since a>0, b>0 and cosh (θ)≥1 the expression under the radicals are reduced as follows.

Clear[E1,E2];
diff2 /. {-Sqrt[E1_^2]+Sqrt[E2_^2]->-(-E1)+E2}

"hyp2a_7.gif"


Copyright © 1999-2007 Donald L. Vossler, Descarta2D Publishing
www.Descarta2D.com