Exploring Analyic Geometry with Mathematica®

Home Contents Commands Packages Explorations Reference
Tour Lines Circles Conics Analysis Tangents

Johnson's Congruent Circle Theorem

johnson.html

Exploration

Take any three circles "johnson_1.gif", "johnson_2.gif" and "johnson_3.gif" which pass through the origin, have equal radii, r, and intersect in pairs in two distinct points (one of the points is, by construction, the origin). Prove that the circle passing through the other three points of intersection between the circles taken in pairs is congruent to the original three circles (that is, this circle has a radius of r).

Approach

Find the coordinates of the intersection points, "johnson_4.gif", "johnson_5.gif" and "johnson_6.gif".  Use the circle through three points function to find Johnson's Circle.  Show that the radius of this circle is r.

Initialize

To initialize Descarta2D, select the input cell bracket and press SHIFT-Enter.

This initialization assumes that the Descarta2D software has been copied into one of the standard directories for AddOns which are on the Mathematica search path, $Path.

<<Descarta2D`

Solution

Without loss of generality, assume the circles have a radius of one and one of them has its center at (1,0). The centers of the other two circles can be written as functions of the angles the lines through (0,0) and the centers makes with the +x axis.

Clear[t2,t3];
P1=Point2D[1,0];
P2=Point2D[Cos[t2],Sin[t2]];
P3=Point2D[Cos[t3],Sin[t3]];

Create the circles.

C1=Circle2D[P1,1];
C2=Circle2D[P2,1];
C3=Circle2D[P3,1];

Intersect the first and second circle to find the intersection points. The head ImPoint2D is introduced to avoid failures during simplification when the coordinates of the points pass through  a temporary phase involving complex numbers.

pts12=Points2D[C1,C2];
pts12=Map[FullSimplify,Map[(ImPoint2D @@ #)&,pts12]];
pts12=Map[(Point2D @@ #)&,pts12]

"johnson_7.gif"

Intersect the first and third circle to find the intersection points.

pts13=Points2D[C1,C3];
pts13=Map[FullSimplify,Map[(ImPoint2D @@ #)&,pts13]];
pts13=Map[(Point2D @@ #)&,pts13]

"johnson_8.gif"

Intersect the second and third circle to find the intersection points.

pts23=Points2D[C2,C3];
pts23=Map[FullSimplify,Map[(ImPoint2D @@ #)&,pts23]];
pts23=Map[(Point2D @@ #)&,pts23]

"johnson_9.gif"

One of the intersection points must be the origin. Which one depends on whether the expression under the radical is positive or negative. We introduce the sign variables "johnson_10.gif", "johnson_11.gif" and "johnson_12.gif" which may only take values of ±1 to cover all the cases.

Clear[s2,s3,s23];
pts12=pts12 //. Sqrt[Sin[t2]^2]->s2*Sin[t2];
pts13=pts13 //. Sqrt[Sin[t3]^2]->s3*Sin[t3];
pts23=pts23 //. Sqrt[Sin[t2-t3]^2]->s23*Sin[t2-t3];

Each pair of intersection points must include the origin as one point. Notice that the other point has the same coordinates no matter which sign is used.

pts12=Map[(pts12 /. s2->#)&, {-1,1}]

"johnson_13.gif"

pts13=Map[(pts13 /. s3->#)&, {-1,1}]

"johnson_14.gif"

pts23=Map[(pts23 /. s23->#)&, {-1,1}]

"johnson_15.gif"

Use one of the non-origin points from each of the intersection lists.

p12=Union[Flatten[pts12]][[2]];
p13=Union[Flatten[pts13]][[2]];
p23=Union[Flatten[pts23]][[2]];

Construct a circle through the three points and examine its radius. Since its radius is one, the circle through the three points is congruent to the other three.

Radius2D[C123=Circle2D[p12,p13,p23]] //FullSimplify

"johnson_16.gif"

Discussion

This is a plot of a numerical example.

Sketch2D[{C1,C2,C3,C123,
          p12,p13,p23} /. {t2->Pi/3,t3->-5Pi/6}]

"johnson_17.gif"

Graphics saved as "johnso01.eps".


Copyright © 1999-2007 Donald L. Vossler, Descarta2D Publishing
www.Descarta2D.com